35.11. Oracle PL/SQLからの移植

例 35-4. 簡単な関数のPL/SQLからPL/pgSQLへの移植

以下はOracle PL/SQLの関数です。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar,
                                                  v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
show errors;

この関数を通じて、PL/pgSQLとの違いを見てみましょう。

• Oracle は IN、OUT、INOUT というパラメータを関数に渡すことができます。 例えば、INOUTはパラメータが値を受け取って別の値を返すことを意味します。 PostgreSQL では "IN" パラメータしかないため、関数は単一の値しか返せません。 したがって、パラメータの種類指定はありません。

• 関数プロトタイプ内の RETURN キーワード (関数本体ではありません) は PostgreSQL では RETURNS になります。 同様に IS は AS になります。 PL/pgSQL 以外の言語でも関数を記述できるため、LANGUAGE 句が必要となります。

• PostgreSQL は関数本体を文字列リテラルと考えます。 したがって、それを囲むドル引用符または他の引用符が必要です。 これは / で終了する Oracle の方法の代替です。

• PostgreSQL には show errors コマンドはありません。 また、エラーが自動的に表示されるため、必要ありません。

それではPostgreSQLに移植されると、この関数がどのようになるか見てみましょう。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name varchar,
                                                  v_version varchar)
RETURNS varchar AS $$
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
$$ LANGUAGE plpgsql;

例 35-5. 他の関数を生成するPL/SQLをPL/pgSQLに移植

以下の手続きは、SELECT文からの行をとって、効率のためにIF文で結果を巨大な関数に埋め込んでいます。 特にカーソルとFORループにおける違いに注目してください。

以下はOracle版です。

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS
    CURSOR referrer_keys IS 
        SELECT * FROM cs_referrer_keys 
        ORDER BY try_order;

    func_cmd VARCHAR(4000); 
BEGIN 
    func_cmd := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN VARCHAR,
                 v_domain IN VARCHAR, v_url IN VARCHAR) RETURN VARCHAR IS BEGIN'; 

    FOR referrer_key IN referrer_keys LOOP 
        func_cmd := func_cmd ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ''' || referrer_key.key_string
          || ''' THEN RETURN ''' || referrer_key.referrer_type
          || '''; END IF;'; 
    END LOOP; 

    func_cmd := func_cmd || ' RETURN NULL; END;'; 

    EXECUTE IMMEDIATE func_cmd; 
END; 
/ 
show errors;

この関数をPostgreSQLで記述するとこうなるでしょう。

CREATE OR REPLACE FUNCTION cs_update_referrer_type_proc() RETURNS void AS $func$
DECLARE
    referrer_keys RECORD;  -- FOR で使用される汎用レコードを宣言
    func_body text;
    func_cmd text;
BEGIN 
    func_body := 'BEGIN' ;

    -- FOR <record> 構文を使用した FOR ループで、問い合わせの結果
    -- をどのようにスキャンしているかに注意してください。

    FOR referrer_key IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        func_body := func_body ||
          ' IF v_' || referrer_key.kind
          || ' LIKE ' || quote_literal(referrer_key.key_string)
          || ' THEN RETURN ' || quote_literal(referrer_key.referrer_type)
          || '; END IF;' ;
    END LOOP; 

    func_body := func_body || ' RETURN NULL; END;';

    func_cmd :=
      'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host varchar,
                                                        v_domain varchar,
                                                        v_url varchar) 
        RETURNS varchar AS '
      || quote_literal(func_body)
      || ' LANGUAGE plpgsql;' ;

    EXECUTE func_cmd;
    RETURN;
END;
$func$ LANGUAGE plpgsql;

関数本体を別途作成し、それを quote_literal に渡して 本体内の引用符を二重化する方法に注目してください。 新規の関数を定義する時ドル引用符の使用が安全とは限らないため、この方法が必要となります。 それは referrer_key.key_string の領域に、どのような文字列が書き込まれているか不明だからです。 (referrer_key.kind は常に信用できる host か domain か url であると仮定しますが、どんなものでも referrer_key.key_string になりうるので、ドル記号を含む可能性があります。) この関数は Oracle 版より実際に改善されています。 それは referrer_key.key_string または referrer_key.referrer_type が引用符を含むとき、おかしなコードを生成しないからです。

例 35-6. 文字列操作を行ない、OUTパラメータを持つPL/SQLプロシージャのPL/pgSQLへの移植

以下の Oracle PL/SQL プロシージャは、URLを解析していくつかの要素(ホスト、パス、問い合わせ)を返します。 PL/pgSQL 関数は 1つしか値を返すことができません。 PostgreSQL での回避方法 の1つとして、複合型 (行型) の戻り値を作成する方法があります。

以下はOracle版です。

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN VARCHAR,
    v_host OUT VARCHAR,  -- この値は戻されます
    v_path OUT VARCHAR,  -- この値も戻されます
    v_query OUT VARCHAR) -- この値も戻されます
IS
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

これを PostgreSQL で記述すると、以下のようになります。

CREATE TYPE cs_parse_url_result AS (
    v_host VARCHAR,
    v_path VARCHAR,
    v_query VARCHAR
);

CREATE OR REPLACE FUNCTION cs_parse_url(v_url VARCHAR)
RETURNS cs_parse_url_result AS $$
DECLARE
    res cs_parse_url_result;
    a_pos1 INTEGER;
    a_pos2 INTEGER;
BEGIN
    res.v_host := NULL;
    res.v_path := NULL;
    res.v_query := NULL;
    a_pos1 := instr(v_url, '//');

    IF a_pos1 = 0 THEN
        RETURN res;
    END IF;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        res.v_host := substr(v_url, a_pos1 + 2);
        res.v_path := '/';
        RETURN res;
    END IF;

    res.v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        res.v_path := substr(v_url, a_pos2);
        RETURN res;
    END IF;

    res.v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    res.v_query := substr(v_url, a_pos1 + 1);
    RETURN res;
END;
$$ LANGUAGE plpgsql;

この関数は以下のように使用できます。

SELECT * FROM cs_parse_url('http://foobar.com/query.cgi?baz');

例 35-7. PL/SQLプロシージャのPL/pgSQLへの移植

以下はOracle版です。

CREATE OR REPLACE PROCEDURE cs_create_job(v_job_id IN INTEGER) IS
    a_running_job_count INTEGER;
    PRAGMA AUTONOMOUS_TRANSACTION;(1)
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;(2)

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        COMMIT; -- ロックを解放(3)
        raise_application_error(-20000, 'Unable to create a new job: a job is currently running.');
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, sysdate);
    EXCEPTION
		WHEN dup_val_on_index THEN NULL; -- 既存であっても問題なし
    END;
    COMMIT;
END;
/
show errors

このようなプロシージャは void 型を返す PostgreSQL 関数に簡単に変換することができます。 これは以下のような事を教えてくれることもあって、このプロシージャは特におもしろいです。

それでは、このプロシージャをPL/pgSQLに移植することができた方法を見てみましょう。

CREATE OR REPLACE FUNCTION cs_create_job(v_job_id integer) RETURNS void AS $$
DECLARE
    a_running_job_count integer;
BEGIN
    LOCK TABLE cs_jobs IN EXCLUSIVE MODE;

    SELECT count(*) INTO a_running_job_count FROM cs_jobs WHERE end_stamp IS NULL;

    IF a_running_job_count > 0 THEN
        RAISE EXCEPTION 'Unable to create a new job: a job is currently running';(1)
    END IF;

    DELETE FROM cs_active_job;
    INSERT INTO cs_active_job(job_id) VALUES (v_job_id);

    BEGIN
        INSERT INTO cs_jobs (job_id, start_stamp) VALUES (v_job_id, now());
    EXCEPTION
        WHEN unique_violation THEN (2)
			-- 既存であっても問題なし
    END;

    RETURN;
END;
$$ LANGUAGE plpgsql;